REM><Invaders$Dir>.Src.Banner
REM Display loading banner...
REM Acorn Invaders (c) DynaByte Software 2007,09.

REM Initialise...
xpos%=0:ypos%=4:xsize%=8:ysize%=12      :REM Position & Size.
x_eig%=16:y_eig%=20                     :REM Screen object stuff.
DIM screen%24,banner%16,blk%20
blk%!0=4:blk%!4=5:blk%!8=11:blk%!12=12:blk%!16=-1
SYS "OS_ReadVduVariables", blk%, blk%
screen%!x_eig%=blk%!0:screen%!y_eig%=blk%!4
screen%!xsize%=(blk%!8)+1<<blk%!0
screen%!ysize%=(blk%!12)+1<<blk%!4

gfx_area%=FNgfx_load("<Invaders$Dir>.Resources.Graphics.Banner")

banner%!xsize%=300<<screen%!x_eig%
banner%!ysize%=100<<screen%!y_eig%
banner%!xpos%=(screen%!xsize%/2)-(banner%!xsize%/2)
banner%!ypos%=(screen%!ysize%/2)-(banner%!ysize%/2)

REM Display our banner...
PROCplot("banner",banner%!xpos%,banner%!ypos%)
END

REM Return the size of a file. (In bytes.)
DEFFNfs_filesize(file$)
 LOCAL size%
 SYS "XOS_File",17,file$ TO ,,,,size%
=size%

REM Load and Decompress GFX data...
REM Doing it this way allows us to use two different buffers, one
REM for the sprites and the other for the charset. All Graphics
REM are compressed using the Squash module. The data is loaded
REM and decompressed to memory, with some munging and a bit of
REM magic here, it becomes our sprite area.
DEFFNgfx_load(filespec$)
 LOCAL size%,wsize%,osize%,buff%,wksp%,area%,status%

 REM Prepare the scene...
 size%=FNfs_filesize(filespec$)                :REM Load the file...
 DIM buff% size%
 SYS "OS_File",16,filespec$,buff%,0

 SYS "Squash_Decompress",1<<3,size% TO wsize%,osize%
 IF osize%=-1 THEN osize%=buff%!4
 DIM wksp% wsize%,area% osize%+4
 area%!0=osize%+4:area%!4=0:area%!8=16:area%!12=16

 REM Decompress to memory & Verify Sprite area...
 SYS "Squash_Decompress",1<<2,wksp%,buff%+20,size%-20,area%+4,osize% TO status%
 IF status%<>0 THEN ERROR 255,"Squash returned non-zero status : "+STR$(status%)
 SYS "OS_SpriteOp", 256+17, area%              :REM Verify data.
=area%

REM Display a sprite at given co-ordinates.
DEFPROCplot(sprite$,x%,y%)
 LOCAL address%
 SYS "OS_SpriteOp", 256+24, gfx_area%, sprite$ TO ,, address%
 SYS "OS_SpriteOp", 512+34, gfx_area%, address%, x%, y%, 0
ENDPROC